在C++中有一種類型叫做聯合體（也叫共用體），它的關鍵字為union，在使用上與結構struct非常相似，可以包含任何的結構類型數據，但它又有一個非常獨特的特性，那就是所有的數據都指向一個地址。

這個意思你可以理解為：聯合體中的所有數據都是引用一個內存塊中相同地址的數據，當我們改變這個聯合體內任何一種數據的值時，其他的數據的值都會隨之改變。

這對于未知類型的數據非常有效，你可以使用聯合體裝載一個數據，然后分析其數據是否有效，或者可以對某些特殊的類型進行位運算，獲取其特殊位置的數值。

但在VB.NET或C#中，根本沒有union關鍵字讓我們聲名聯合體，但該怎么做才能聲名聯合體呢？

這需要用到結構屬性！

讓我們看看如何將下面的C++聯合體代碼轉換為一個VB.NET的聯合結構吧！

union myunion  
{  
char b; //單字節整數，在c語言中用char類型來表示單字節整數  
short s; //雙字節整數  
int i; //四字節整數  
}  

這個聯合體大小為4個字節，其各個數據分別表示為單字節、雙字節、四字節的整數，在運行期間其任何數據的改變都會影響其他數據。

Improts System.Runtime.InteropServices '引入運行時非托管數據管理服務 

引入結構屬性，精確控制結構中元素的位置

<StructLayout(LayoutKind.Explicit)> _  
Structure MyUnion  
' 設置字段的偏移值，設為0即可  
<FieldOffset(0)> Dim b As Byte '單字節整數  
<FieldOffset(0)> Dim s As Short '雙字節整數  
<FieldOffset(0)> Dim i As Integer '四字節整數  
End Structure  

這就是在.NET中設置聯合結構的方法，C#中于VB.NET中的設置方法雷同，這里就不做贅述了。

下面來介紹聯合體的特性應用，就以上面我們剛才聲名的聯合體結構為例，下面的代碼將為我們演示聯合體的特性：

Dim MU As New MyUnion  
MsgBox(String.Format("{0} {1} {2}", MU.b, MU.s, MU.i)) '0 0 0  
MU.s = Int16.MaxValue  
MsgBox(String.Format("{0} {1} {2}", MU.b, MU.s, MU.i)) '255 32767 32767  
MU.b = 12  
MsgBox(String.Format("{0} {1} {2}", MU.b, MU.s, MU.i)) '12 32524 32524  
MU.i = 0  
MsgBox(String.Format("{0} {1} {2}", MU.b, MU.s, MU.i)) '0 0 0  

上面的代碼可以更直觀地顯示數據在內存中的變化，每當改變聯合數據時，其他的數據也會隨著內存的變化而變化。

當然，使用聯合體也有限制，那就是.NET的聯合體只適用于值類型，無法應用在引用類型和指針中，你無法設置字符串(String)或是數組進入聯合類型，這一點需要非常的注意！

當然，.NEt中的聯合結構體并不只有上面的用法，你可以發揮自己的想象力，比如可以：

<StructLayout(LayoutKind.Explicit)> _  
Structure MyUnion2  
<FieldOffset(0)> Dim b1 As Byte 
<FieldOffset(1)> Dim b2 As Byte 
<FieldOffset(2)> Dim b3 As Byte 
<FieldOffset(3)> Dim b4 As Byte 
<FieldOffset(0)> Dim i As Integer 
<FieldOffset(0)> Dim ui As UInteger  
End Structure  

這個結構可以獲取一個有或無符號的四個字節整數每一個字節的數據，而不需要自己寫算法來分析了。

測試代碼：

Code：

Dim MU As MyUnion2  
MsgBox(MU.i & " : " & MU.ui) '0 : 0  
MsgBox(String.Format("{0} {1} {2} {3}", Hex(MU.b1), Hex(MU.b2), Hex(MU.b3), Hex(MU.b4))) '0 0 0 0  
MU.b1 = 255 : MU.b2 = 255 : MU.b3 = 255 : MU.b4 = 255  
MsgBox(String.Format("{0} {1} {2} {3}", Hex(MU.b1), Hex(MU.b2), Hex(MU.b3), Hex(MU.b4))) 'FF FF FF FF  
MsgBox(MU.i & " : " & MU.ui) '-1 : 4294967295 

【編輯推薦】

1. 深入C# 序列化(Serialize)、反序列化(Deserialize)
2. C#初學者對Equals方法的幾個常見誤解
3. 詳談C#和.NET中的類型轉換
4. C#中自增、自減操作符重載是個怎么回事兒
5. C#中的閉包是怎么捕獲變量的